{
  description = "Albatros";
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs";
  };

  outputs = { self, nixpkgs }: 
    let
      system = "x86_64-linux";
      nixuniverse = import (builtins.fetchGit {
        url = "https://git.deuxfleurs.fr/quentin/nixuniverse.git";
        ref = "main";
        rev = "e94fa51007c9a51ac233e4fcfca09249102f74c5";
      });
      pkgs = import nixpkgs {
        inherit system;
        overlays = [ nixuniverse ];
      };
      gopkg = arch: (pkgs.buildGoModule rec {
        pname = "albatros-go-module";
        version = "0.9";
        src = ./.;
        CGO_ENABLED = 0;
        vendorSha256 = "sha256-Q7gImRoJqtcORpHLQoF3TRK2WJu3tKSjSE3Sno6lNNk=";
        checkPhase = "true";
        meta = with pkgs.lib; {
          description = "albatros is a CI for Nomad";
          homepage = "https://git.deuxfleurs.fr/quentin/albatros";
          license = licenses.agpl3;
          platforms = platforms.linux;
        };
      }).overrideAttrs (old: old // { GOOS = "linux"; GOARCH = arch; });
      albatros = arch: pkgs.stdenv.mkDerivation {
        pname = "albatros";
        version = "0.9";
        unpackPhase = "true";
        installPhase = ''
          cp `find ${gopkg arch}/bin -name albatros` $out
        '';
      };
      docker = staticBin: arch: pkgs.dockerTools.buildImage {
        name = "dxflrs/albatros";
        architecture = arch;
        config = {
         Cmd = [ "${staticBin}" ];
        };
      };
    in
      {
        packages.aarch64-linux.albatros = albatros "arm64" ;
        packages.aarch64-linux.docker.albatros = docker self.packages.aarch64-linux.albatros "arm64";
        packages.aarch64-linux.default = self.packages.aarch64-linux.albatros;

        packages.x86_64-linux.albatros = albatros "amd64";
        packages.x86_64-linux.docker.albatros = docker self.packages.x86_64-linux.albatros "amd64";
        packages.x86_64-linux.default = self.packages.x86_64-linux.albatros;

        devShell.x86_64-linux = pkgs.mkShell { buildInputs = [ pkgs.kaniko pkgs.manifest-tool ]; };
      };
}